|
|
| T.F.S.B.I.G.W.S. |
| Posted: Apr 9 2008, 04:32 PM |
 |
|
Advanced Member
Group: Members
Posts: 39
Member No.: 22223
Joined: 8-October 07
|
Hello
I have prepared 5643 images (at the moment saved as both TIFs and PNGs) and I need to save them as a movie (AVI or whatever). I downloaded Adobe Flash Pr (30 days) and haven't, as yet been able to make head or tail. I also downloaded Gif Movie Gear and made a bit more progress with that but, while applications like Irfanview and Windows Movie Maker can sort the numbered files OK, it seems to randomise some of the files.
I would appreciate it if anyone could help me out here - or perhaps Virtualdub could do the trick (I tried Virtualdub and didn't get very far with it).
Thanks |
|
| T.F.S.B.I.G.W.S. |
| Posted: Apr 9 2008, 08:35 PM |
|
|
Advanced Member
Group: Members
Posts: 39
Member No.: 22223
Joined: 8-October 07
|
I have had another look at Gif Movie Gear and the problem is that it seems to be adding a number to the title of each file as it opens it - but the files are already numbered and the new files appear in the window in incorrect sequence related to the new numbers which Gif Move Gear has created. |
|
| DarrellS |
| Posted: Apr 10 2008, 07:53 AM |
|
|
Advanced Member
Group: Members
Posts: 567
Member No.: 1061
Joined: 28-November 02
|
I've seen a few programs that will put the first file last and the last file first but I've never seen Gif Movie Gear do this or put the files in the wrong order and I've been using it since it first came out. I assume the problem is that Movie Gear doesn't support TIFF files. You'll need to use batch conversion in Irfanview.
Since you have 5643 images I assume your first image is number 0001. If it is 1 or 01 or 001 then that is a problem also. You'll need to manually rename all of the wrong numbered files and that will take some time.
I wouldn't store a lot of images in one folder. I'd put 100 or 200 images in each folder and only join one folder at a time. You can go back when you're done with each folder and join the separate AVIs.
Virtualdub will work for PNG but not for TIFF and again, the images need to be named correctly for Virtualdub to open them in the correct order. |
|
| T.F.S.B.I.G.W.S. |
| Posted: Apr 10 2008, 04:18 PM |
|
|
Advanced Member
Group: Members
Posts: 39
Member No.: 22223
Joined: 8-October 07
|
Thanks DarrellS. Irfanview is able to work with 1 & 2 & 3 (as is Windows Movie Maker) but I have now commenced a renumbering task. |
|
| foxidrive |
| Posted: Apr 11 2008, 02:53 AM |
|
|
Advanced Member
Group: Members
Posts: 918
Member No.: 16996
Joined: 21-October 05
|
This might help you: save it as plain text in a file called renumber.cmd and execute it for the help screen.
It takes the list of files as they appear in a DIR /B listing so if that order is not how you need them then some modification is necessary (IE create a text file with the filenames in the order you need and parse that)
EG use "DIR *.tiff /b >filelist.txt" and edit the file.
| CODE |
::Renumber.cmd:::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 2004-03-10 - Idea from foxidrive in a.m.b.nt
:: 2004-03-10 - Enhanced by Matthias Tacke
:: 2004-03-11 - Rejigged again by foxidrive
@echo off
setlocal enableextensions
if [%1]==[] goto :Usage
:: the following two lines disable the persistent Offset/RenInc
set /A Offset=1
set /A RenInc=1
if not [%2]==[] set Prefix=%~2
if not [%3]==[] set /A NumLen=%3
if not [%4]==[] set /A Offset=%4
if not [%5]==[] set /A RenInc=%5
set RealExt=%~x1
set TempExt=%RealExt:.=.tmp_%
set DrvPath=%~dp1
if NOT defined Offset set /A Offset=1
if NOT defined RenInc set /A RenInc=1
:: Check for valid files to rename
for /f %%A in ('dir %1 /a-d /b 2^>nul^|find /c /v ""') do set RenCnt=%%A
if %RenCnt%==0 echo There are no "%1" files to rename. & goto :EOF
set /A RenMax=(Offset+(RenCnt*RenInc))-RenInc
:: Check if previous UNDO file exists
set ask=
if exist "%DrvPath%UndoRenumb.cmd" (
echo The last UNDO file "%DrvPath%UndoRenumb.cmd" is still usable,
set /p ask="do you wish to overwrite it? (Y/N) :"
)
if exist "%DrvPath%UndoRenumb.cmd" (
if /i [%ask%]==[Y] (del "%DrvPath%UndoRenumb.cmd") else (goto :EOF))
:: Routine to check the highest number used
:: and increase NumLen if required
set ask=
set count=0
:findlength
set /a count+=1
call set RenMaxLen=%%RenMax:~0,%count%%%
if not %RenMaxLen%==%RenMax% goto :findlength
if NOT defined NumLen set /a NumLen=%count%
if %NumLen% LSS %count% (
echo The Numeral Length has been changed from %NumLen% to %count%
echo to accomodate the highest numeral needed for the rename - %RenMax%
set /p ask="Continue? [Y/N] :"
set /a NumLen=count
)
if /i [%ask%]==[N] goto :EOF
:: Body of routine to pass each filename to the Renumb routine
:: then rename all files with a temp extension to the real extension
:start
for /F "tokens=*" %%A in ('dir %1 /b /on /a-d') do Call :Renumb "%%A"
Ren "%DrvPath%*%TempExt%" *%RealExt%
endlocal & set /A Offset=%Offset%& set /A RenInc=%RenInc%
goto :EOF
:: routine to do the renumbering and renaming
:Renumb
set RenNew=00000000000000000000%Offset%
call set RenNew=%%RenNew:~-%NumLen%%%
Ren %1 "%Prefix%%RenNew%%TempExt%"
>>"%DrvPath%UndoRenumb.cmd" echo Ren "%~dp1%Prefix%%RenNew%%RealExt%" %1
set /a Offset=Offset+RenInc
goto :EOF
:Usage
echo.Usage: %0 file.ext ["Pre fix"] [#NumLength] [#Begin] [#Increment]
echo.
echo.To rename files to a new name, consisting of a prefix
echo.followed by an incrementing numeral (and the original extension)
echo.
echo."Pre fix" - is the prefix for your files
echo. (use "" if no prefix is desired and other options needed)
echo.#NumLength - EG: using 3 adds 001 as the numeral
echo.
echo.#Begin - Number to start the renaming at
echo.
echo.#Increment - Number to add to successive elements
echo.
echo.Example: %~f0 *.jpg "Model Planes " 3
echo. will rename all JPG files to "Model Planes nnn.JPG"
echo. where nnn is a number from 001 to 999
echo.
echo.An UNDO batch file "UndoRenumb.cmd" is generated in the file directory
::echo.The Offset and Increment values are preserved between successive runs
echo.Arguments in brackets are optional but the order is important:
echo.I.E. If you need increment then all other arguments must be included.
::Renumber.cmd:::::::::::::::::::::::::::::::::::::::::::::::::::::::
|
|
|
| T.F.S.B.I.G.W.S. |
| Posted: Apr 12 2008, 07:44 PM |
|
|
Advanced Member
Group: Members
Posts: 39
Member No.: 22223
Joined: 8-October 07
|
Thanks foxidrive.
I also received this:
Go to www.powersurgepub.com and download PS Renamer
- or get it from www.versiontracker.com
split your files into 3 folders
ie those needing 3 zeros, those needing 2, and those needing 1
Then just run the app on each folder
but by the time I had received that and your advice I had already renumbered most of the effected files.
I am now almost ready to save as a gif or avi (or whatever).
|
|
