|
|
| Spider-Mann |
| Posted: Aug 22 2012, 06:59 PM |
 |
|
Newbie
Group: Members
Posts: 3
Member No.: 33819
Joined: 15-December 11
|
Hello, i want to do the following:
Video encoding with the internal x264vfw-Codec.
Audio encoding with the internal ac3acm-Codec.
Multiplexing with an external mkvmerge.
Is this possible, and when yes, how can i do this?
|
|
| dloneranger |
| Posted: Aug 22 2012, 07:35 PM |
|
|
Moderator
Group: Moderators
Posts: 2366
Member No.: 22158
Joined: 26-September 07
|
If you want to do it that way, the easiest thing to do is save as an avi, and then turn the avi into an mkv
A batch file makes it all nice and easy
change the set mkvmerge=....... to point to the right place and save this as a .bat file, then you can just drag avi's onto the .bat file
| CODE | @echo off
rem set path to mkvmerge.exe here
set mkvmerge="%cd%\mkvmerge.exe"
:loop
set DataFullFilePath=%~1
set DataFileName=%~n1
set Outputfile=%~dpn1.mkv
if "%DataFullFilePath%."=="." goto nomore
echo MKV'ing %DataFileName%
rem ----------------
rem this next bit is one long line, but it's wrapped in the code block
rem ----------------
%mkvmerge% -q -o "%Outputfile%" "--language" "0:eng" "--default-track" "0:yes" "--forced-track" "0:no" "--language" "1:eng" "--default-track" "1:yes" "--forced-track" "1:no" "-a" "1" "-d" "0" "-S" "-T" "--no-global-tags" "--no-chapters" "(" "%DataFullFilePath%" ")" "--track-order" "0:0,0:1"
rem ----------------
rem end of the long line
rem ----------------
if %ERRORLEVEL% gtr 0 goto mergeerror
goto loopdone
:mergeerror
echo Error %errorlevel% mkv'ing file
echo "%DataFullFilePath%"
echo to
echo "%Outputfile%"
pause
:loopdone
@echo.
@shift
@goto loop
:nomore
@echo.
@echo ------------------------------------
@echo All Done
@pause
@exit
|
If you'd rather do it with external encoders you can look here
http://forums.virtualdub.org/index.php?act...=ST&f=3&t=18840
--------------------
MultiAdjust JoinWav WavNormalize FFMPeg Input Plugin v1827 UnSharpMask
Windows7/8 Codec Chooser
All FccHandlers Stuff inc. Installers for acm codecs AAC, AC3, LameMp3 |
|
| Spider-Mann |
| Posted: Aug 22 2012, 08:10 PM |
|
|
Newbie
Group: Members
Posts: 3
Member No.: 33819
Joined: 15-December 11
|
Thank you, that's exactly what I'm doing at the moment, but without script. |
|
