|
|
| raffriff42 |
| Posted: Sep 7 2014, 05:22 PM |
 |
|
Advanced Member
Group: Members
Posts: 384
Member No.: 35081
Joined: 25-June 12
|
| QUOTE (supermax @ Sep 7 2014, 02:29 PM) | | Another thing that I think would be more, is spending several configurations ...so, if you need, I can make various modifications without having to change the batch file |
Good idea! I will try that!
| QUOTE (supermax @ Sep 7 2014, 02:29 PM) | | I must need to use those filters that you directed in another topic (alias format and confert format)? |
No, not needed. It seems that VirtualDub sends video to external encoders in one format only (assuming the documentation is up to date...) "The color space is 4:2:0 YCbCr using Rec. 601 limited-range, 8-bit per channel encoding. The normal excursions are 16-235 for luma and 16-240 for chroma, but values from 0-255 may be encoded."
However, this is not a problem if your source is Rec709; simply make sure you keep your video in YV12 format from end-to-end: this means setting Video, Color depth, output to "YV12" or "Same as decompression" and - using either "fast recompress" if no filters are needed, or
- making sure not to use any filters that require RGB mode, or
- (worst option) converting to RGB for the filter, then back to YV12
If there are no YUV<>RGB conversions, all you need to do is tell to encoder that this should be flagged as Rec709: this does not change any bitstream data, it simply tells the playback side how to display it. In other words, VirtualDub and x264 don't know or care whether the bitstream represents Rec601 or Rec709 (or bt2020, or...), only your decoding application does. |
|
| raffriff42 |
| Posted: Sep 7 2014, 05:30 PM |
|
|
Advanced Member
Group: Members
Posts: 384
Member No.: 35081
Joined: 25-June 12
|
Just finished and tested my own 2-pass batch files! Works fine in normal or batch encoding mode.
- Note the muxer must overwrite the output file without error, or pass 2 will fail.
(if using ffmpeg to mux, use the -y switch)
- Note "V bat x264 3k5 pass2" actually sends "--pass 3" to x264:
per the docs, "--pass 3" is used for the "final" pass.
(EDIT as mentioned below, not everybody may want this, but it's easily changed).
@supermax, I did not see your suggestions until it was too late to incorporate them, unfortunately.
EDIT 8-Sep-2014 fixed typo "--colorprim %7" etc (thanks dloneranger)
V-x264-2pass.bat | CODE | @echo off
:: USAGE W H fpsnum fpsden output-path bitrate pass [matrix=none]
:: 1 2 3 4 5 6 7 8
::** CONFIGURATION SECTION **
set x264="C:\VirtualDub\excoders\x264\x264.exe"
::** END CONFIGURATION SECTION **
@echo **** VIDEO: X264 (pass %7) ***********
if (%1)==() goto BADARG
if (%2)==() goto BADARG
if (%3)==() goto BADARG
if (%4)==() goto BADARG
if (%5)==() goto BADARG
if (%6)==() goto BADARG
if (%7)==() goto BADARG
if %1 lss 16 goto BADARG
if %2 lss 16 goto BADARG
if %3 lss 1 goto BADARG
if %4 lss 1 goto BADARG
if %7 lss 1 goto BADARG
if %7 gtr 3 goto BADARG
if (%8)==() set a_matrix=
if (%8)==() goto NOMATRIX
set a_matrix=--colorprim %8 --transfer %8 --colormatrix %8
:NOMATRIX
set a_br=%6
set a_tune=--preset slow
::set a_deblock=
set a_deblock=--deblock -1:-1
@echo %time%
ver > nul
@echo on
%x264% --pass %7 --bitrate %a_br% %a_tune% %a_deblock% ^
--demuxer raw --stats "%~dpn5-stats" ^
--input-res %1x%2 --fps %3/%4 ^
%a_matrix% --no-progress -o %5 -
@echo off
@echo %time%
if ERRORLEVEL 1 goto DUMPARGS
if %7 equ 3 del /q "%~dpn5-stats*"
exit 0
:BADARG
@echo VIDEO ERROR: BAD OR MISSING ARGUMENT
goto DUMPARGS
:DUMPARGS
@echo USAGE W H fpsnum fpsden output-path bitrate pass [matrix=none]
if (%1)==() goto :DUMPEND
if (%2)==() goto :DUMPEND
@echo input-size = %1x%2
if (%3)==() goto :DUMPEND
if (%4)==() goto :DUMPEND
@echo fps = %3/%4
if (%5)==() goto :DUMPEND
@echo output = %5
if (%6)==() goto :DUMPEND
@echo bitrate = %6
if (%7)==() goto :DUMPEND
@echo pass = %7
if (%8)==() goto :DUMPEND
@echo matrix = %8
:DUMPEND
exit 1
|
This .vdprof omits the audio (I went with NeroAAC here, after trying to get ffmpeg to do AAC and failing) and muxer (MP4); they will go in my next post.
excoder mp4 ff+x264 3500 2pass (V).vdprof | CODE | {
"description": "VirtualDub external encoder profile collection",
"externalEncoders": {
"sets": {
"mp4 x264 3k5 +aac pass1": {
"videoEncoder": "V bat x264 3k5 pass1",
"audioEncoder": "",
"multiplexer": "",
"description": "mp4",
"extension": "mp4",
"processPartial": true,
"useOutputAsTemp": false
},
"mp4 x264 3k5 +aac pass2": {
"videoEncoder": "V bat x264 3k5 pass2",
"audioEncoder": "A bat nero aac q035",
"multiplexer": "M bat ff mp4",
"description": "mp4",
"extension": "mp4",
"processPartial": true,
"useOutputAsTemp": false
}
},
"profiles": {
"V bat x264 3k5 pass1": {
"name": "V bat x264 3k5 pass1",
"program": "V-x264-2pass.bat",
"commandArguments": "%(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" 3500 1",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": true
},
"V bat x264 3k5 pass2": {
"name": "V bat x264 3k5 pass2",
"program": "V-x264-2pass.bat",
"commandArguments": "%(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" 3500 3",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": true
}
}
}
}
|
This post has been edited by raffriff42 on Sep 8 2014, 11:02 PM |
|
| raffriff42 |
| Posted: Sep 7 2014, 05:35 PM |
|
|
Advanced Member
Group: Members
Posts: 384
Member No.: 35081
Joined: 25-June 12
|
Here are the audio and muxer files; you may have them already if you have been following my previous posts. There is one important change however: as mentioned above, the muxer should have the overwrite option enabled, or pass 2 will fail.
M-mp4-ffmpeg.bat| CODE | @echo off
::** CONFIGURATION SECTION **
set ffmpeg="C:\VirtualDub\excoders\ffmpeg\ffmpeg.exe"
::** END CONFIGURATION SECTION **
@echo **** MUXING: ffmpeg ***********
if (%1)==() goto BADARG
if (%2)==() goto BADARG
if (%3)==() goto BADARG
if not exist %1 goto BADARG
if not exist %2 goto BADARG
if /I (%~x3) neq (.mp4) goto BADEXT
set ffps=-r %4
if (%4)==() set ffps=
if exist %3 del /f %3
@echo %time%
ver > nul
@echo on
%ffmpeg% -y -hide_banner -i %1 -i %2 %ffps% -c:v copy -c:a copy -f mp4 -movflags faststart %3
@echo off
@echo %time%
if ERRORLEVEL 1 goto DUMPARGS
::@echo on
::copy /y %3 "%~dpn3-$bak.mp4"
::@echo off
exit 0
:BADARG
@echo MUXER ERROR: BAD OR MISSING ARGUMENT
goto DUMPARGS
:BADEXT
@echo MUXER ERROR: OUTPUT FILE EXTENSION NOT .MP4
goto DUMPARGS
:DUMPARGS
@echo USAGE video-src-path audio-src-path output-path
if (%1)==() goto :DUMPEND
@echo video-src = %1
if (%2)==() goto :DUMPEND
@echo audio-src = %2
if (%3)==() goto :DUMPEND
@echo output = %3
if (%4)==() goto :DUMPEND
@echo fps = %4
:DUMPEND
exit 1
|
A-nero-aac.bat| CODE | @echo off
::** CONFIGURATION SECTION **
set nero_aac="C:\VirtualDub\excoders\neroaac\neroAacEnc.exe"
::** END CONFIGURATION SECTION **
@echo **** AUDIO: Nero AAC ***********
:: USAGE %(channels) %(audioprecision) %(samplingrate) output-path [qfactor=0.35]
:: 1 2 3 4 5
:: approx. average bitrate <-> Quality table
::
:: Quality Bitrate
:: bad 0.05 .... ~ 16
:: 0.15 ~ 33
:: 0.25 ~ 66
:: good (default) 0.35 .... ~ 100
:: 0.45 ~ 146
:: better 0.55 .... ~ 192
:: 0.65 ~ 238
:: 0.75 ~ 285
:: ridiculous 0.85 .... ~ 332
:: 0.95 ~ 382
if (%1)==() goto BADARG
if (%2)==() goto BADARG
if (%3)==() goto BADARG
if (%4)==() goto BADARG
if %1 leq 0 goto BADARG
if %1 gtr 8 goto BADARG
if %2 lss 16 goto BADARG
if %2 gtr 32 goto BADARG
if %3 lss 22050 goto BADARG
if %3 gtr 96000 goto BADARG
if not (%5)==() set qual=%5
if (%5)==() set qual=0.35
if %qual% lss 0.01 goto BADARG
if %qual% gtr 0.95 goto BADARG
if exist %4 del /f %4
@echo %time%
ver > nul
@echo on
%nero_aac% -q %qual% -ignorelength -if - -of %4
@echo off
@echo %time%
if ERRORLEVEL 1 goto DUMPARGS
exit 0
:BADARG
@echo AUDIO ERROR: BAD OR MISSING ARGUMENT
goto DUMPARGS
:DUMPARGS
@echo USAGE channels bitwidth samplingrate output-path [qfactor=0.35]
if (%1)==() goto :DUMPEND
@echo channels = %1
if (%2)==() goto :DUMPEND
@echo bitwidth = %2
if (%3)==() goto :DUMPEND
@echo samplingrate = %3
if (%4)==() goto :DUMPEND
@echo output = %4
if (%5)==() goto :DUMPEND
@echo qfactor = %5
:DUMPEND
exit 1
|
excoder mp4 ff+x264 3500 2pass (A,M).vdprof| CODE | {
"description": "VirtualDub external encoder profile collection",
"externalEncoders": {
"profiles": {
"M bat ff mp4": {
"name": "M bat ff mp4",
"program": "M-mp4-ffmpeg.bat",
"commandArguments": "\"%(tempvideofile)\" \"%(tempaudiofile)\" \"%(outputfile)\" %(fps)",
"outputFilename": "",
"type": 2,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
},
"A bat nero aac q035": {
"name": "A bat nero aac q035",
"program": "A-nero-aac.bat",
"commandArguments": "%(channels) %(audioprecision) %(samplingrate) \"%(tempaudiofile)\" 0.35",
"outputFilename": "%(outputname).aac",
"type": 1,
"inputFormat": 1,
"checkReturnCode": true,
"logStdout": true,
"logStderr": false,
"bypassCompression": true,
"predeleteOutputFile": false
}
}
}
}
|
|
|
| supermax |
| Posted: Sep 8 2014, 07:58 PM |
|
|
Member
Group: Members
Posts: 15
Member No.: 38193
Joined: 1-August 14
|
very nice.
I would not erase stats file. Because if something goes wrong on stage something muxer (or even audio) I do not need to repeat the first pass, I can just redo the second pass.
Its very practical idea to make just one batch file to the two stages of 2pass. |
|
| raffriff42 |
| Posted: Sep 8 2014, 11:01 PM |
|
|
Advanced Member
Group: Members
Posts: 384
Member No.: 35081
Joined: 25-June 12
|
| QUOTE (supermax @ Sep 8 2014, 07:58 PM) | | I would not erase stats file... |
Sounds reasonable. That's easy to change in the GUI dialog, according to personal preference (Options, External encoders, Edit "V bat x264 3k5 pass2", change last arg from "3" to "2")
|
|
| supermax |
| Posted: Sep 9 2014, 12:04 PM |
|
|
Member
Group: Members
Posts: 15
Member No.: 38193
Joined: 1-August 14
|
Following your ideas I made my first batch Generic file. In theory, it was a single batch file for everything, where you can use any x264 command. See Below, tested and worked in crf, pass1, pass2, abr:
V-x264-full.bat
| CODE |
@echo off
::** CONFIGURATION SECTION **
set x264="D:\Videos\excoders\x264\x264.exe"
::** END CONFIGURATION SECTION **
@echo *********** VIDEO: X264 ***********
:: USAGE command W H fpsnum fpsden output-path [matrix=none]
:: 1 2 3 4 5 6 7
if (%1)==() goto BADARG
if (%2)==() goto BADARG
if (%3)==() goto BADARG
if (%4)==() goto BADARG
if (%5)==() goto BADARG
if (%6)==() goto BADARG
if %2 lss 1 goto BADARG
if %3 lss 1 goto BADARG
if %4 lss 1 goto BADARG
if %5 lss 1 goto BADARG
if (%7)==() set a_matrix=
if (%7)==() goto NOMATRIX
set a_matrix=--colorprim %7 --transfer %7 --colormatrix %7
:NOMATRIX
set a_command=%~1
::ex.: --crf 18 --preset placebo --me umh --merange 32 --subme 11 --ref 6 --bframes 3 --deblock -1:-1 --b-adapt 2 --tune film --demuxer raw
if exist %6 del /f %6
@echo %time%
ver > nul
@echo on
%x264% %a_command% --input-res %2x%3 --fps %4/%5 %a_matrix% --no-progress -o %6 -
@echo off
@echo %time%
if ERRORLEVEL 1 goto DUMPARGS
:: If you want to delete the statistics, should be something like this
::if exist "%~dpn6-stats*" del /q "%~dpn6-stats*"
exit 0
:BADARG
@echo VIDEO ERROR: BAD OR MISSING ARGUMENT
goto DUMPARGS
:DUMPARGS
@echo USAGE W H fpsnum fpsden output-path crf [matrix=none]
if (%1)==() goto :DUMPEND
@echo command = %~6
if (%2)==() goto :DUMPEND
if (%3)==() goto :DUMPEND
@echo input-size = %1x%2
if (%4)==() goto :DUMPEND
if (%5)==() goto :DUMPEND
@echo fps = %3/%4
if (%6)==() goto :DUMPEND
@echo output = %5
if (%7)==() goto :DUMPEND
@echo matrix = %7
:DUMPEND
exit 1
|
samples.vdprof
| CODE |
{
"description": "VirtualDub external encoder profile collection",
"externalEncoders": {
"sets": {},
"profiles": {
".V x264 CRF": {
"name": ".V x264 CRF",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--crf 18 --preset placebo --me umh --merange 32 --subme 11 --ref 6 --bframes 3 --deblock -1:-1 --b-adapt 2 --tune film --demuxer raw\" %(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
},
".V x264 pass1": {
"name": ".V x264 pass1",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--pass 1 --bitrate 3500 --preset placebo --me hex --merange 12 --subme 5 --ref 3 --bframes 3 --deblock -1:-1 --tune film --direct auto --demuxer raw --b-adapt 2 --stats \"%(tempvideofile).stats\" \" %(width) %(height) %(fpsnum) %(fpsden) NUL bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
},
".V x264 pass2": {
"name": ".V x264 pass2",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--pass 2 --bitrate 3500 --preset placebo --me umh --merange 32 --subme 10 --ref 8 --bframes 3 --deblock -1:-1 --tune film --direct auto --demuxer raw --stats \"%(tempvideofile).stats\" \" %(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
},
".V x264 ABR": {
"name": ".V x264 ABR",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--pass 1 --bitrate 3500 --preset placebo --me umh --merange 24 --subme 6 --ref 6 --bframes 3 --deblock -1:-1 --tune film --direct auto --demuxer raw --b-adapt 2 --stats \"%(tempvideofile).stats\" \" %(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
}
}
}
}
|
audio and muxed just follow the already public options. The idea was just to simplify files and increase the possibility of settings |
|
| raffriff42 |
| Posted: Sep 9 2014, 12:26 PM |
|
|
Advanced Member
Group: Members
Posts: 384
Member No.: 35081
Joined: 25-June 12
|
Great! Beautifully simple! This eliminates the need for multiple related batch files with different encoder settings, and puts the settings into the GUI where they belong! 
I think I had better go back and update my files at top of thread, with kudos to you of course. Will do as soon as possible. |
|
| supermax |
| Posted: Sep 9 2014, 02:03 PM |
|
|
Member
Group: Members
Posts: 15
Member No.: 38193
Joined: 1-August 14
|
| QUOTE (raffriff42 @ Sep 9 2014, 12:26 PM) | Great! Beautifully simple! This eliminates the need for multiple related batch files with different encoder settings, and puts the settings into the GUI where they belong!
I think I had better go back and update my files at top of thread, with kudos to you of course. Will do as soon as possible. |
Many thanks for your compliment.
I did not see if you noticed, I opted to leave the commands in the beginning, because I believe it is easier to use.
I've found a problem: When the name of the video output has space or some character as simple - or.
example:
video p1.mp4
Video.p1.mp4
Video-p1.mp4
I do not understand anything Batch programming, but I believe that I have not declared a string variable (a_command) the best way. or also, may perhaps declare otherwise or commandArguments
| QUOTE |
"commandArguments": "\ "--pass 1 --bitrate 3500 --preset placebo --me hex --merange 12 --subme 5 --ref 3 --bframes 3 --deblock -1: -1 filme --tune --direct auto - -demuxer cru --b-se adaptar 2 --stats \ "% (tempvideofile) .stats \" \ "% (largura)% (altura)% (fpsnum)% (fpsden) NUL BT709",
|
|
|
| supermax |
| Posted: Sep 11 2014, 04:34 PM |
|
|
Member
Group: Members
Posts: 15
Member No.: 38193
Joined: 1-August 14
|
All done, everything settled and working 100%
practically only changed one line for not giving more problem with filenames containing spaces " "
this was the change
| QUOTE |
%x264% %a_command% --input-res %2x%3 --fps %4/%5 %a_matrix% --no-progress -o %6 -
|
| QUOTE |
%x264% %a_command:'="% --input-res %2x%3 --fps %4/%5 %a_matrix% --no-progress -o %6 -
|
Important notice: also changed the way we report the file name Statistics in command arguments.
And must be used: a single quote (') instead of double quotes (")
| QUOTE |
"--pass 1 --bitrate 1400 --preset placebo --me hex --merange 12 --subme 5 --ref 3 --bframes 3 --deblock -1:-1 --tune film --direct auto --demuxer raw --b-adapt 2 --stats '%(tempvideofile).stats' " %(width) %(height) %(fpsnum) %(fpsden) NUL bt709
|
everything else remains the same, anyway follows everything completed to facilitate:
| CODE |
@echo off
::** CONFIGURATION SECTION **
set x264="D:\Videos\excoders\x264\x264.exe"
::** END CONFIGURATION SECTION **
@echo *********** VIDEO: X264 ***********
:: USAGE command W H fpsnum fpsden output-path [matrix=none]
:: 1 2 3 4 5 6 7
if (%1)==() goto BADARG
if (%2)==() goto BADARG
if (%3)==() goto BADARG
if (%4)==() goto BADARG
if (%5)==() goto BADARG
if (%6)==() goto BADARG
if %2 lss 1 goto BADARG
if %3 lss 1 goto BADARG
if %4 lss 1 goto BADARG
if %5 lss 1 goto BADARG
if (%~7)==() set a_matrix=
if (%~7)==() goto NOMATRIX
set a_matrix=--colorprim %7 --transfer %7 --colormatrix %7
:NOMATRIX
:: https://support.google.com/youtube/answer/1722171?hl=en
:: x264 --crf 18.0 --preset "veryfast" --bframes 2 --keyint 15
set a_command=%~1
if exist %6 del /f %6
@echo %time%
ver > nul
@echo on
%x264% %a_command:'="% --input-res %2x%3 --fps %4/%5 %a_matrix% --no-progress -o %6 -
@echo off
@echo %time%
MSG * VirtualDub completou uma tarefa
if ERRORLEVEL 1 goto DUMPARGS
exit 0
:BADARG
@echo VIDEO ERROR: BAD OR MISSING ARGUMENT
goto DUMPARGS
:DUMPARGS
@echo USAGE Command W H fpsnum fpsden output-path [matrix=none]
if (%1)==() goto :DUMPEND
@echo command = %~6
if (%2)==() goto :DUMPEND
if (%3)==() goto :DUMPEND
@echo input-size = %1x%2
if (%4)==() goto :DUMPEND
if (%5)==() goto :DUMPEND
@echo fps = %3/%4
if (%6)==() goto :DUMPEND
@echo output = %5
if (%7)==() goto :DUMPEND
@echo matrix = %7
:DUMPEND
exit 1
|
| CODE |
{
"description": "VirtualDub external encoder profile collection",
"externalEncoders": {
"sets": {},
"profiles": {
".V x264 CRF": {
"name": ".V x264 CRF",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--crf 18 --preset placebo --me umh --merange 32 --subme 11 --ref 6 --bframes 3 --deblock -1:-1 --b-adapt 2 --tune film --demuxer raw\" %(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
},
".V x264 pass1": {
"name": ".V x264 pass1",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--pass 1 --bitrate 3500 --preset placebo --me hex --merange 12 --subme 5 --ref 3 --bframes 3 --deblock -1:-1 --tune film --direct auto --demuxer raw --b-adapt 2 --stats \'%(tempvideofile).stats\' \" %(width) %(height) %(fpsnum) %(fpsden) NUL bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
},
".V x264 pass2": {
"name": ".V x264 pass2",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--pass 2 --bitrate 3500 --preset placebo --me umh --merange 32 --subme 10 --ref 8 --bframes 3 --deblock -1:-1 --tune film --direct auto --demuxer raw --stats \'%(tempvideofile).stats\' \" %(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
},
".V x264 ABR": {
"name": ".V x264 ABR",
"program": "excoders\\V-x264-full.bat",
"commandArguments": "\"--pass 1 --bitrate 3500 --preset placebo --me umh --merange 24 --subme 6 --ref 6 --bframes 3 --deblock -1:-1 --tune film --direct auto --demuxer raw --b-adapt 2 --stats \'%(tempvideofile).stats\' \" %(width) %(height) %(fpsnum) %(fpsden) \"%(tempvideofile)\" bt709",
"outputFilename": "%(outputname).264",
"type": 0,
"inputFormat": 0,
"checkReturnCode": true,
"logStdout": true,
"logStderr": true,
"bypassCompression": false,
"predeleteOutputFile": false
}
}
}
}
|
Finally I have included a warning that "Virtualdub finished a task," I wanted a beep or a warning sound, but could not save the command in the batch file (ALT+16 e ALT+7)
Who does not want to just remorer line. |
|
| raffriff42 |
| Posted: Sep 11 2014, 07:35 PM |
|
|
Advanced Member
Group: Members
Posts: 384
Member No.: 35081
Joined: 25-June 12
|
| QUOTE | | I wanted a beep or a warning sound |
"@echo " + Alt+Numberpad 0,0,0,7
(Ctrl-G (ASCII 7) =beep, but you can't enter Ctrl-G directly; you enter char 0x07 with Alt+Numberpad 0,0,0,7)
In case I am not making sense:
https://www.google.com/search?q=batch+file+beep
Will try your script later, got to run... |
|
| supermax |
| Posted: Sep 12 2014, 11:35 AM |
|
|
Member
Group: Members
Posts: 15
Member No.: 38193
Joined: 1-August 14
|
| QUOTE (raffriff42 @ Sep 11 2014, 07:35 PM) | | QUOTE | | I wanted a beep or a warning sound |
"@echo " + Alt+Numberpad 0,0,0,7
(Ctrl-G (ASCII 7) =beep, but you can't enter Ctrl-G directly; you enter char 0x07 with Alt+Numberpad 0,0,0,7)
In case I am not making sense:
https://www.google.com/search?q=batch+file+beep
Will try your script later, got to run... |
eureka !!!! 
was exactly what I wanted !!! that simple thing!
I searched google for this, but in my language. And I had only seen the bid Ctrl + Alt + G or 7. But to work gotta edit in the text editor msdos; lot of work to get do changes.
Thanks. |
|
|
