|
|
| Jane |
| Posted: Nov 4 2013, 06:05 AM |
 |
|
Newbie
Group: Members
Posts: 1
Member No.: 37392
Joined: 4-November 13
|
Hi!
I am a complete newbie to not only VirtualDub but to the whole video editing world itself so I apologize in advance for asking what is probably a super simple question but because of my lack of base knowledge on this subject I find myself currently stumped.
I have a bunch of avi files that I want to pull a bunch of images out of -- but it is so frustrating for me to have to add each of the avi files to the job control list one by one and then save as image sequence to pull out the jpgs.
I know you are able to process entire directories of avi file but is there a way to batch process a bunch of avi clips to pull an image sequence out of?
Thanks for the help everyone, trying to figure out this problem on my own has been driving me crazy.  |
|
| -vdub- |
| Posted: Nov 4 2013, 05:09 PM |
|
|
Advanced Member
Group: Members
Posts: 613
Member No.: 27087
Joined: 24-February 10
|
. |
|
| dloneranger |
| Posted: Nov 4 2013, 06:31 PM |
|
|
Moderator
Group: Moderators
Posts: 2366
Member No.: 22158
Joined: 26-September 07
|
Not using virtualdub's jobs list is easier
How about a .bat file that will save a sequence?
You can drag a single or multiple videos to it
If so, save this as eg SaveImgSeq.bat on your desktop (or where ever else you like)
| CODE | @echo off
rem set your path to virtualdubs folder here
rem no quotes for VirtualdubFolder
set VirtualdubFolder=c:\something\virtualdub
set vdub="%VirtualdubFolder%\vdub.exe"
rem if using 64bit virtualdub delete the rem from the next line
rem set vdub="%VirtualdubFolder%\vdub64.exe"
if not exist %vdub% echo Cannot find virtaldub & pause & goto :eof
rem pFrameCountToSave = number of frames to save, 0=all
set pFrameCountToSave=4
rem pFrameStartAt = start saving from frame #
set pFrameStartAt=0
rem pImageType 1=targa, 2=jpg, 3=png
rem for jpg, pSaveOption=quality%
rem for targa pSaveOption is ignored so you can use any number
rem for png pSaveOption = 0 for quick compress, = 100 for normal
rem pNumberOfDigits = number of digits for frame number in filename
set pImageType=2
set pFileExt=".jpg"
set pSaveOption=95
set pNumberOfDigits=5
:loopfiles
if %1.==. goto alldone
set MySettings="%~dpn1_toseq.vdscript"
>%MySettings% echo VirtualDub.Open(VirtualDub.params[0],"",0);
>>%MySettings% echo VirtualDub.video.SetPreserveEmptyFrames(0);
>>%MySettings% echo VirtualDub.video.SetFrameRate2(0,0,1);
>>%MySettings% echo VirtualDub.video.SetIVTC(0, 0, 0, 0);
>>%MySettings% echo VirtualDub.video.filters.Clear();
>>%MySettings% echo VirtualDub.audio.filters.Clear();
if %pFrameCountToSave%==0 goto skipframecount
>>%MySettings% echo VirtualDub.video.SetRangeFrames(%pFrameStartAt%,%pFrameCountToSave%);
:skipframecount
>>%MySettings% echo VirtualDub.SaveImageSequence(VirtualDub.params[1], %pFileExt%, %pNumberOfDigits%, %pImageType%, %pSaveOption%);
:skipwritesettings
rem if you want to save in a specific folder use something like set OutputSeq="c:\somewhere\%~n1"
set OutputSeq="%~dpn1"
set InputVideo=%1
@echo Saving %~nx1
%vdub% /i %MySettings% %InputVideo% %OutputSeq% /x
if not errorlevel 1 goto nextfile
echo "An error happened"
pause
goto :eof
:nextfile
if exist %MySettings% del %MySettings%
shift
goto loopfiles
:alldone
echo.
echo All files saved
pause |
Change this bit set VirtualdubFolder=c:\something\virtualdub to whatever folder your virtualdub is in
eg
set VirtualdubFolder=c:\users\fred\desktop\virtualdub
There are other options you can change
Look for the lines starting with rem and they'll tell you what each one does
Then you can just drag files to it and it'll work it's way through them one after another
--------------------
MultiAdjust JoinWav WavNormalize FFMPeg Input Plugin v1827 UnSharpMask
Windows7/8 Codec Chooser
All FccHandlers Stuff inc. Installers for acm codecs AAC, AC3, LameMp3 |
|
|
